#!/usr/bin/env perl

use warnings;
use strict;
use Carp;

## report the program and machine
use Sys::Hostname;
my $host = hostname();
print "\n\n";
print "Starting script $0 on $host\n\n";

use vars qw( $VERSION );
$VERSION = '0.01';

use IPC::Cmd 0.36 qw( can_run run );
use PS::IPP::Metadata::Config;
use PS::IPP::Metadata::Stats;
use PS::IPP::Metadata::List qw( parse_md_list );

use File::Temp qw( tempfile );

use PS::IPP::Config qw($PS_EXIT_SUCCESS
		       $PS_EXIT_UNKNOWN_ERROR
		       $PS_EXIT_SYS_ERROR
		       $PS_EXIT_CONFIG_ERROR
		       $PS_EXIT_PROG_ERROR
		       $PS_EXIT_DATA_ERROR
		       $PS_EXIT_TIMEOUT_ERROR
		       caturi
		       );
my $ipprc = PS::IPP::Config->new(); # IPP configuration

use Getopt::Long qw( GetOptions :config auto_help auto_version gnu_getopt );
use Pod::Usage qw( pod2usage );

my ($exp_tag, $cam_id, $recipe, $camera, $dbname, $workdir, $reduction, $dvodb, $no_update, $no_op);
GetOptions(
	   'exp_tag=s'          => \$exp_tag, # Exposure identifier
	   'cam_id=s'          => \$cam_id, # Camtool identifier
	   'recipe=s'          => \$recipe, # Recipe to use
	   'camera|c=s'        => \$camera, # Camera
	   'dbname|d=s'        => \$dbname, # Database name
	   'workdir|w=s'       => \$workdir, # Working directory
	   'reduction=s'       => \$reduction, # Reduction class		       
	   'dvodb|w=s'         => \$dvodb,  # output DVO database
	   'no-update'         => \$no_update, # Update the database?
	   'no-op'             => \$no_op, # Don't do any operations?
	   ) or pod2usage( 2 );

pod2usage( -msg => "Unknown option: @ARGV", -exitval => 2 ) if @ARGV;
pod2usage(
    -msg => "Required options: --exp_tag --cam_id --camera",
    -exitval => 3,
) unless defined $exp_tag
    and defined $cam_id
    and defined $camera;

$ipprc->define_camera($camera);

# Recipes to use based on reduction class
$reduction = 'DEFAULT' unless defined $reduction;

my $recipe1 = $ipprc->reduction($reduction, 'JPEG_BIN1'); # Recipe to use
&my_die("Unrecognised JPEG recipe", $cam_id, $PS_EXIT_CONFIG_ERROR) unless defined $recipe1;

my $recipe2 = $ipprc->reduction($reduction, 'JPEG_BIN2'); # Recipe to use
&my_die("Unrecognised JPEG recipe", $cam_id, $PS_EXIT_CONFIG_ERROR) unless defined $recipe2;

# values to extract from output metadata and the stats to calculate
my $CHIPSTATS = 
   [   
       #          PPSTATS KEYWORD         STATISTIC          CHIPTOOL FLAG
	{ name => "bg",             type => "mean",  flag => "-bg",            	dtype => "float" },
	{ name => "bg_mean_stdev",  type => "stdev", flag => "-bg_mean_stdev", 	dtype => "float" },
	{ name => "bg_stdev",       type => "rms",   flag => "-bg_stdev",      	dtype => "float" },  

# these should be coming from the psastro results for Nimfile > 1, 
	{ name => "sigma_ra",       type => "rms",   flag => "-sigma_ra",      	dtype => "float" },  
	{ name => "sigma_dec",      type => "rms",   flag => "-sigma_dec",     	dtype => "float" },  
	{ name => "n_stars",        type => "sum",   flag => "-n_stars",       	dtype => "int"   },  
	{ name => "n_astrom",       type => "sum",   flag => "-n_astrom",      	dtype => "int"   },  

	{ name => "fwhm",           type => "mean",  flag => "-fwhm",          	dtype => "float" },  

# these are not defined for the database table camProcessedExp
#	{ name => "ap_resid",       type => "mean",  flag => "-ap_resid",      	dtype => "float" },  
#	{ name => "ap_resid_stdev", type => "rms",   flag => "-ap_resid_stdev", dtype => "float" },  
#       { name => "fringe_0",       type => "mean",  flag => "-fringe_0",      	dtype => "float" },  
#       { name => "fringe_1",       type => "rms",   flag => "-fringe_1",      	dtype => "float" },  
#       { name => "fringe_0",       type => "stdev", flag => "-fringe_2",      	dtype => "float" },  
   ];
my $chipStats = PS::IPP::Metadata::Stats->new($CHIPSTATS); # Stats parser

# Look for programs we need
my $missing_tools;
my $camtool = can_run('camtool') or (warn "Can't find camtool" and $missing_tools = 1);
my $ppImage = can_run('ppImage') or (warn "Can't find ppImage" and $missing_tools = 1);

# test for addstar and psastro:
my $psastro = can_run('psastro') or (warn "Can't find psastro" and $missing_tools = 1);
my $addstar = can_run('addstar') or (warn "Can't find addstar" and $missing_tools = 1);

if ($missing_tools) { 
    warn("Can't find required tools.");
    exit($PS_EXIT_CONFIG_ERROR); 
}

my $mdcParser = PS::IPP::Metadata::Config->new;	# Parser for metadata config files

# Get list of component files
my $files;			# Array of component files
{
    my $command = "$camtool -pendingimfile -cam_id $cam_id"; # Command to run
    $command .= " -dbname $dbname" if defined $dbname;
    my ( $success, $error_code, $full_buf, $stdout_buf, $stderr_buf ) =
	run(command => $command, verbose => 1);
    unless ($success) {
	$error_code = (($error_code >> 8) or $PS_EXIT_PROG_ERROR);
	&my_die("Unable to perform camtool: $error_code", $cam_id, $error_code);
    }
    my $metadata = $mdcParser->parse(join "", @$stdout_buf) or
	&my_die("Unable to parse metadata config doc", $cam_id, $PS_EXIT_PROG_ERROR);

    # extract the metadata for the files into a hash list
    $files = parse_md_list($metadata) or
	&my_die("Unable to parse metadata list", $cam_id, $PS_EXIT_PROG_ERROR);

    # extract the stats from the metadata
    unless ($chipStats->parse($metadata)) {
	&my_die("Unable to find all values in statistics output.\n", $cam_id, $PS_EXIT_PROG_ERROR);
    }
}

my ($list1File, $list1Name) = tempfile( "$exp_tag.cm.$cam_id.b1.list.XXXX", UNLINK => 1 ); # For binning 1
my ($list2File, $list2Name) = tempfile( "$exp_tag.cm.$cam_id.b2.list.XXXX", UNLINK => 1 ); # For binning 2
my ($list3File, $list3Name) = tempfile( "$exp_tag.cm.$cam_id.b3.list.XXXX", UNLINK => 1 ); # For astrometry

my $chipObjects; 
my $chipObjectsExist = 0;
foreach my $file (@$files) {
    # use the path_base as OUTPUT root and convert the filenames with ipprc->filename:
    my $class_id = $file->{class_id};

    # If there is only one chip, we use this name for the input to addstar
    $chipObjects = $ipprc->filename("PSASTRO.OUTPUT", $file->{path_base}, $class_id);
    print $list1File ($ipprc->filename("PPIMAGE.BIN1", $file->{path_base}, $class_id) . "\n");
    print $list2File ($ipprc->filename("PPIMAGE.BIN2", $file->{path_base}, $class_id) . "\n");
    print $list3File ($chipObjects . "\n");

     # if any of the output chip astrometry files exist, we can run psastro / addstar below
    if ($ipprc->file_exists($chipObjects)) {
	$chipObjectsExist = 1;
    }
}
close $list1File;
close $list2File;
close $list3File;

# Output products
$workdir = caturi( $workdir, $exp_tag ) if defined $workdir;
my $outputRoot = $ipprc->file_prepare( "$exp_tag.cm.$cam_id", $workdir, ${$files}[0]->{path_base} );

my $jpeg1      = $ipprc->filename("PPIMAGE.JPEG1", $outputRoot); # Binned JPEG #1
my $jpeg2      = $ipprc->filename("PPIMAGE.JPEG2", $outputRoot); # Binned JPEG #2
my $fpaObjects = $ipprc->filename("PSASTRO.OUTPUT.MEF", $outputRoot); # MEF psastro output

# convert supplied DVO database name to UNIX filename
my $dvodbReal;
if (defined $dvodb) {
    $dvodbReal = $ipprc->convert_filename_absolute( $dvodb );
}

unless ($no_op) {

    ## build the output JPEG images first so we get them even if the astrometry fails

    # Make the jpeg for binning 1
    {
	my $command = "$ppImage -list $list1Name $outputRoot -recipe PPIMAGE $recipe1"; # Command to run
	my ( $success, $error_code, $full_buf, $stdout_buf, $stderr_buf ) =
	    run(command => $command, verbose => 1);
	unless ($success) {
	    $error_code = (($error_code >> 8) or $PS_EXIT_PROG_ERROR);
	    &my_die("Unable to perform ppImage: $error_code", $cam_id, $error_code);
	}
	&my_die("Unable to find expected output file: $jpeg1", $cam_id, $PS_EXIT_PROG_ERROR) unless -f $ipprc->file_resolve($jpeg1);
    }

    # Make the jpeg for binning 2
    {
	my $command = "$ppImage -list $list2Name $outputRoot -recipe PPIMAGE $recipe2"; # Command to run
	my ( $success, $error_code, $full_buf, $stdout_buf, $stderr_buf ) =
	    run(command => $command, verbose => 1);
	unless ($success) {
	    $error_code = (($error_code >> 8) or $PS_EXIT_PROG_ERROR);
	    &my_die("Unable to perform ppImage: $error_code", $cam_id, $error_code);
	}
	&my_die("Unable to find expected output file: $jpeg2", $cam_id, $PS_EXIT_PROG_ERROR) unless -f $ipprc->file_resolve($jpeg2);
    }

    # only run psastro / addstar if any of the output chip astrometry files exist
    if ($chipObjectsExist) {
	# run psastro +mosastro on the set of chips or copy the chipObjects to fpaObjects
	# XXX note that this is wrong if imfiles are cells
	# XXX add a ppStats call which will collect the astrometry stats
	if (scalar @$files > 1) {
	    my $command = "$psastro -list $list3Name $outputRoot +mosastro -chipastro " . 
		"-F PSASTRO.OUTPUT PSASTRO.OUTPUT.MEF";
	    my ( $success, $error_code, $full_buf, $stdout_buf, $stderr_buf ) =
		run(command => $command, verbose => 1);
	    unless ($success) {
		$error_code = (($error_code >> 8) or $PS_EXIT_PROG_ERROR);
		&my_die("Unable to perform psastro: $error_code", $cam_id, $error_code);
	    }
	} else {
	    $ipprc->file_copy($chipObjects, $fpaObjects) unless $chipObjects eq $fpaObjects;
	}
	&my_die("Unable to find expected output file: $fpaObjects", $cam_id, $PS_EXIT_PROG_ERROR) unless -f $ipprc->file_resolve($fpaObjects);

	# run addstar on either the single chip output or the single fpa output
	# XXX this construct requires the user to have a valid .ptolemyrc 
	# XXX which in turn points at ippconfig/dvo.site
	
	# require a defined output dvo database to run addstar (ie, refuse to use the .ptolemyrc default)
	# XXX this needs to be converted to addstar_client...
	if (defined $dvodbReal) {
	    my $camdir = $ipprc->dvo_cameradir(); # Camera directory for addstar
	    my $command = "$addstar -D CAMERA $camdir " . $ipprc->file_resolve($fpaObjects);
	    $command .= " -D CATDIR $dvodbReal";

	    my ( $success, $error_code, $full_buf, $stdout_buf, $stderr_buf ) =
		run(command => $command, verbose => 1);
	    unless ($success) {
		$error_code = (($error_code >> 8) or $PS_EXIT_PROG_ERROR);
		&my_die("Unable to perform addstar: $error_code", $cam_id, $error_code);
	    }
	}
    }
    
}

my $fpaCommand = "$camtool -addprocessedexp";
$fpaCommand .= " -cam_id $cam_id";
$fpaCommand .= " -uri UNKNOWN";
$fpaCommand .= " -path_base $outputRoot";
$fpaCommand .= " -dbname $dbname" if defined $dbname;
$fpaCommand .= $chipStats->cmdflags();

# Add the result into the database
unless ($no_update) {
    my ( $success, $error_code, $full_buf, $stdout_buf, $stderr_buf ) =
	run(command => $fpaCommand, verbose => 1);
    unless ($success) {
	$error_code = (($error_code >> 8) or $PS_EXIT_PROG_ERROR);
	warn("Unable to perform dettool -addprocessedexp: $error_code\n");
	exit($error_code);
    }
} else {
    print "skipping command: $fpaCommand\n";
}


sub my_die
{
    my $msg = shift; # Warning message on die
    my $cam_id = shift; # Camtool identifier
    my $exit_code = shift; # Exit code to add

    carp($msg);
    if ($cam_id and not $no_update) {
	my $command = "$camtool -addprocessedexp -cam_id $cam_id -uri UNKNOWN -code $exit_code";
	$command .= " -dbname $dbname" if defined $dbname;
        system ($command);
    }
    exit $exit_code;
}


END {
    my $status = $?;
    system("sync") == 0
        or die "failed to execute sync: $!" ;
    $? = $status;
}

__END__
