#!/usr/bin/env perl

use warnings;
use strict;

use IPC::Cmd qw( can_run run );
use PS::IPP::Metadata::Config;
use PS::IPP::Metadata::List qw( parse_md_list );
use Data::Dumper;

use Getopt::Long qw( GetOptions :config auto_help auto_version gnu_getopt );
use Pod::Usage qw( pod2usage );

my ($dbname,			# Database name to use
    $workdir,			# Working directory
    );
GetOptions(
	   'dbname|d=s'  => \$dbname,
	   'workdir|w=s' => \$workdir,
) or pod2usage( 2 );

pod2usage(
	  -msg => "Required options: --dbname",
	  -exitval => 3,
	  ) unless defined $dbname;

my $mdcParser = PS::IPP::Metadata::Config->new;	# Metadata config parser

# Look for programs we need
my $missing_tools;
my $regtool = can_run('regtool') or (warn "Can't find regtool" and $missing_tools = 1);
my $register_imfile = can_run('register_imfile.pl') or (warn "Can't find register_imfile.pl" and $missing_tools = 1);
my $register_exp = can_run('register_exp.pl') or (warn "Can't find register_exp.pl" and $missing_tools = 1);
die "Can't find required tools.\n" if $missing_tools;

# Phase 0 imfile processing
my $list;
{
    my $command = "$regtool -pendingimfile -dbname $dbname"; # Command to run
    my ( $success, $error_code, $full_buf, $stdout_buf, $stderr_buf ) =
	run( command => $command, verbose => 1 );
    die "Unable to get phase 0 imfile list: $error_code\n" if not $success;
    $list = parse_md_list( $mdcParser->parse( join( '', @$stdout_buf ) ) ) or
	die "Unable to parse output from regtool.\n";
}

foreach my $item (@$list) {
    my $exp_tag = $item->{exp_tag};
    my $class = $item->{class};
    my $class_id = $item->{class_id};
    my $uri = $item->{uri};
    
    my $command = "$register_imfile --exp_tag $exp_tag --class $class --class_id $class_id --uri $uri --dbname $dbname";
    $command .= " --workdir $workdir" if defined $workdir;
    my ( $success, $error_code, $full_buf, $stdout_buf, $stderr_buf ) =
	run( command => $command, verbose => 1 );
    die "Unable to do phase 0 imfile processing on $exp_tag $class_id: $error_code\n" if not $success;
}

# Phase 0 exposure processing
{
    my $command = "$regtool -pendingexp -dbname $dbname"; # Command to run
    my ( $success, $error_code, $full_buf, $stdout_buf, $stderr_buf ) =
	run( command => $command, verbose => 1 );
    die "Unable to get phase 0 exposure list: $error_code\n" if not $success;
    $list = parse_md_list( $mdcParser->parse( join( '', @$stdout_buf ) ) ) or
	die "Unable to parse output from regtool.\n";
}

foreach my $item (@$list) {
    my $exp_tag = $item->{exp_tag};
    
    my $command = "$register_exp --exp_tag $exp_tag --dbname $dbname";
    $command .= " --workdir $workdir" if defined $workdir;
    my ( $success, $error_code, $full_buf, $stdout_buf, $stderr_buf ) =
	run( command => $command, verbose => 1 );
    die "Unable to do phase 0 exposure processing on $exp_tag: $error_code\n" if not $success;
}

END {
    my $status = $?;
    system("sync") == 0
        or die "failed to execute sync: $!" ;
    $? = $status;
}


__END__


