#!/usr/bin/env perl

use warnings;
use strict;

## report the program and machine
use Sys::Hostname;
my $host = hostname();
print "\n\n";
print "Starting script $0 on $host\n\n";

use vars qw( $VERSION );
$VERSION = '0.01';

use IPC::Cmd qw( can_run run );
use PS::IPP::Metadata::Config;
use PS::IPP::Metadata::Stats;

use PS::IPP::Config qw(
    $PS_EXIT_SUCCESS
    $PS_EXIT_UNKNOWN_ERROR
    $PS_EXIT_SYS_ERROR
    $PS_EXIT_CONFIG_ERROR
    $PS_EXIT_PROG_ERROR
    $PS_EXIT_DATA_ERROR
    $PS_EXIT_TIMEOUT_ERROR
    );
my $ipprc = PS::IPP::Config->new(); # IPP configuration
use File::Spec;

use Getopt::Long qw( GetOptions :config auto_help auto_version gnu_getopt );
use Pod::Usage qw( pod2usage );

my ($det_id, $exp_tag, $class_id, $det_type, $input_uri, $camera, $dbname, $workdir, $no_update, $no_op);
GetOptions(
    'det_id|d=s'        => \$det_id,
    'exp_tag|e=s'       => \$exp_tag,
    'class_id|i=s'      => \$class_id,
    'det_type|t=s'      => \$det_type,
    'input_uri|u=s'     => \$input_uri,
    'camera|c=s'        => \$camera,
    'dbname|d=s'        => \$dbname, # Database name
    'workdir|w=s'       => \$workdir, # Working directory, for output files
    'no-update'         => \$no_update,
    'no-op'             => \$no_op,
) or pod2usage( 2 );

pod2usage( -msg => "Unknown option: @ARGV", -exitval => 2 ) if @ARGV;
pod2usage(
    -msg => "Required options: --det_id --exp_tag --class_id --det_type --input_uri --camera",
    -exitval => 3,
) unless defined $det_id
    and defined $exp_tag
    and defined $class_id
    and defined $det_type
    and defined $input_uri
    and defined $camera;

# XXX this exits with status = 0 on failure
$ipprc->define_camera($camera);

# Recipes to use, as a function of the detrend type
use constant RECIPES => {
    'bias'    => 'PPIMAGE_O',	 # Overscan only
    'dark'    => 'PPIMAGE_OB',	 # Overscan and bias only
    'shutter' => 'PPIMAGE_OBD',	 # Overscan, bias and dark only
    'flat'    => 'PPIMAGE_OBDS', # Overscan, bias, dark and shutter only
    'domeflat'    => 'PPIMAGE_OBDS', # Overscan, bias, dark and shutter only
    'skyflat'    => 'PPIMAGE_OBDS', # Overscan, bias, dark and shutter only
    'fringe'  => 'PPIMAGE_OBDSF',# Overscan, bias, dark, shutter and flat only
};

# Look for programs we need
my $missing_tools;
my $dettool = can_run('dettool') or (warn "Can't find dettool" and $missing_tools = 1);
my $ppImage = can_run('ppImage') or (warn "Can't find ppImage" and $missing_tools = 1);
if ($missing_tools) { 
    warn("Can't find required tools.");
    exit($PS_EXIT_CONFIG_ERROR); 
}
$ppImage .= " -dbname $dbname" if defined $dbname;

# Recipe to use in processing
my $recipe = RECIPES->{lc($det_type)};
unless (defined $recipe) {
    warn("Unrecognised detrend type: $det_type");
    exit($PS_EXIT_CONFIG_ERROR);
}

### Output file name
if (defined $workdir) {
    $workdir = $ipprc->convert_filename_absolute( $workdir );
} else {
    my ($vol, $dir, $file) = File::Spec->splitpath( $input_uri );
    $workdir = $dir;
}
my $outputFile = "$exp_tag.detproc.$det_id"; # Root name
my $outputRoot = File::Spec->catfile( $workdir, $exp_tag, $outputFile );
my $outputImage = $ipprc->filename("PPIMAGE.OUTPUT", $outputRoot, $class_id);
my $outputBin1 = $ipprc->filename("PPIMAGE.BIN1", $outputRoot, $class_id);
my $outputBin2 = $ipprc->filename("PPIMAGE.BIN2", $outputRoot, $class_id);

my $outputStats = $outputRoot . '.' . $class_id . '.stats';

$input_uri = $ipprc->convert_filename_absolute( $input_uri );

# Run ppImage
my $stats = PS::IPP::Metadata::Stats->new(); # Stats parser
unless ($no_op) {
    my $command = "$ppImage -file $input_uri $outputRoot -recipe PPIMAGE $recipe" .
	" -stat $outputStats"; # Command to run ppImage
    my ( $success, $error_code, $full_buf, $stdout_buf, $stderr_buf ) =
	run(command => $command, verbose => 1);
    unless ($success) {
	$error_code = (($error_code >> 8) or $PS_EXIT_PROG_ERROR);
	&my_die("Unable to perform ppImage: $error_code", $det_id, $exp_tag, $class_id, $error_code);
    }
    &my_die("Couldn't find expected output file: $outputImage", $det_id, $exp_tag, $class_id, $PS_EXIT_SYS_ERROR) unless -f $outputImage;
    &my_die("Couldn't find expected output file: $outputStats", $det_id, $exp_tag, $class_id, $PS_EXIT_SYS_ERROR) unless -f $outputStats;
    &my_die("Couldn't find expected output file: $outputBin1", $det_id, $exp_tag, $class_id, $PS_EXIT_SYS_ERROR) unless -f $outputBin1;
    &my_die("Couldn't find expected output file: $outputBin2", $det_id, $exp_tag, $class_id, $PS_EXIT_SYS_ERROR) unless -f $outputBin2;

    # Get the statistics on the processed image
    my $statsFile;		# File handle
    open $statsFile, "$outputStats" or die "Can't open statistics file $outputStats: $!\n";
    my @contents = <$statsFile>; # Contents of file
    close $statsFile;
    my $mdcParser = PS::IPP::Metadata::Config->new;	# Parser for metadata config files
    my $metadata = $mdcParser->parse(join "", @contents)
        or &my_die("Unable to parse metadata config", $det_id, $exp_tag, $class_id, $PS_EXIT_PROG_ERROR);
    $stats->parse($metadata) or &my_die("Unable to find all values in statistics output.", $det_id, $exp_tag, $class_id, $PS_EXIT_PROG_ERROR);
}

# Take off the absolute path, to stuff into the database
$outputImage = $ipprc->convert_filename_relative( $outputImage );
$outputRoot = $ipprc->convert_filename_relative( $outputRoot );

my $bg = ($stats->bg_mean() or 'NAN');
my $bg_stdev = ($stats->bg_stdev() or 'NAN');
my $bg_mean_stdev = ($stats->bg_mean_stdev() or 'NAN');

# Add the processed file to the database
unless ($no_update) {
    my $command = "$dettool -addprocessedimfile -det_id $det_id -exp_tag $exp_tag " .
	"-class_id $class_id -recip $recipe -uri $outputImage -path_base $outputRoot"; # Command to run dettool
    $command .= " -bg $bg -bg_stdev $bg_stdev -bg_mean_stdev $bg_mean_stdev";
    $command .= " -dbname $dbname" if defined $dbname;

    my ( $success, $error_code, $full_buf, $stdout_buf, $stderr_buf ) =
	run(command => $command, verbose => 1);
    unless ($success) {
	$error_code = (($error_code >> 8) or $PS_EXIT_PROG_ERROR);
	warn("Unable to perform dettool -addprocessedimfile: $error_code\n");
	exit($error_code);
    }

    unlink $outputStats;
}

sub my_die
{
    my $msg = shift; # Warning message on die
    my $det_id = shift;		# Detrend identifier
    my $exp_tag = shift; # Exposure tag
    my $class_id = shift; # Class identifier
    my $exit_code = shift; # Exit code to add

    warn($msg);
    if ($det_id and $exp_tag and $class_id and not $no_update) {
	my $command = "$dettool -addprocessedimfile -det_id $det_id -exp_tag $exp_tag -class_id $class_id -code $exit_code";
	$command .= " -dbname $dbname" if defined $dbname;
        system ($command);
    }
    exit $exit_code;
}

END {
    my $status = $?;
    system("sync") == 0
        or die "failed to execute sync: $!" ;
    $? = $status;
}

__END__
