#!/usr/bin/env perl

use warnings;
use strict;

## report the program and machine
use Sys::Hostname;
my $host = hostname();
print "\n\n";
print "Starting script $0 on $host\n\n";

use IPC::Cmd qw( can_run run );
use PS::IPP::Metadata::Config;
use PS::IPP::Metadata::Stats;
use Data::Dumper;
use PS::IPP::Config qw(
    $PS_EXIT_SUCCESS
    $PS_EXIT_UNKNOWN_ERROR
    $PS_EXIT_SYS_ERROR
    $PS_EXIT_CONFIG_ERROR
    $PS_EXIT_PROG_ERROR
    $PS_EXIT_DATA_ERROR
    $PS_EXIT_TIMEOUT_ERROR
    );
my $ipprc = PS::IPP::Config->new(); # IPP configuration
use File::Spec;

use Getopt::Long qw( GetOptions :config auto_help auto_version gnu_getopt );
use Pod::Usage qw( pod2usage );

use constant RECIPE => 'PPIMAGE_OBDSFRA'; # Recipe to use

# Parse the command-line arguments
my ($exp_tag,			# Exposure tag
    $class_id,			# Class Id
    $input,			# Input FITS file
    $camera,			# Camera
    $dbname,			# Database name
    $workdir,			# Working directory, for output files
    $no_update,			# Don't update the database?
    $no_op,			# Don't do any operations?
    );
GetOptions(
    'exp_tag|e=s'   => \$exp_tag,
    'class_id|i=s'  => \$class_id,
    'uri|u=s'       => \$input,
    'camera|c=s'    => \$camera,
    'dbname|d=s'    => \$dbname, # Database name
    'workdir|w=s'   => \$workdir,
    'no-update'     => \$no_update,
    'no-op'         => \$no_op,
) or pod2usage( 2 );

pod2usage( -msg => "Unknown option: @ARGV", -exitval => 2 ) if @ARGV;
pod2usage(
    -msg => "Required options: --exp_tag --class_id --uri --camera",
    -exitval => 3,
) unless defined $exp_tag 
    and defined $class_id 
    and defined $input
    and defined $camera;

$ipprc->define_camera($camera);

# Look for programs we need
my $missing_tools;
my $chiptool = can_run('chiptool') or (warn "Can't find chiptool" and $missing_tools = 1);
my $ppImage = can_run('ppImage') or (warn "Can't find ppImage" and $missing_tools = 1);
if ($missing_tools) { 
    warn("Can't find required tools.");
    exit($PS_EXIT_CONFIG_ERROR); 
}
$ppImage .= " -dbname $dbname" if defined $dbname;

$input = $ipprc->convert_filename_absolute( $input );

if (defined $workdir) {
    $workdir = $ipprc->convert_filename_absolute( $workdir );
} else {
    my ($vol, $dir, $file) = File::Spec->splitpath( $input );
    $workdir = $dir;
}

$workdir = File::Spec->catfile( $workdir, $exp_tag );
system "mkdir -p $workdir" unless -d $workdir;

### Output file name --- must match camera configuration!
my $outputFile =  "$exp_tag.chip";
my $outputRoot = File::Spec->catfile( $workdir, $outputFile );
my $outputImage = $ipprc->filename("PPIMAGE.OUTPUT", $outputRoot, $class_id);
my $outputBin1 = $ipprc->filename("PPIMAGE.BIN1", $outputRoot, $class_id);
my $outputBin2 = $ipprc->filename("PPIMAGE.BIN2", $outputRoot, $class_id);
my $outputStats = $outputRoot  . '.' . $class_id . '.stats';

my $stats = PS::IPP::Metadata::Stats->new(); # Stats parser
unless ($no_op) {
    # Run ppImage
    print "outputImage: $outputImage\n";
    print "outputBin1: $outputBin1\n";
    print "outputStats: $outputStats\n";
    
    my $command = "$ppImage -file $input $outputRoot -recipe PPIMAGE " . RECIPE .
	" -stat $outputStats"; # Command to run ppImage
    my ( $success, $error_code, $full_buf, $stdout_buf, $stderr_buf ) =
	run(command => $command, verbose => 1);
    unless ($success) {
	$error_code = (($error_code >> 8) or $PS_EXIT_PROG_ERROR);
	&my_die("Unable to perform ppImage: $error_code", $exp_tag, $class_id, $error_code);
    }
    &my_die("Couldn't find expected output file: $outputImage\n", $exp_tag, $class_id, $PS_EXIT_SYS_ERROR) unless -f $outputImage;
    &my_die("Couldn't find expected output file: $outputBin1\n", $exp_tag, $class_id, $PS_EXIT_SYS_ERROR) unless -f $outputBin1;
    &my_die("Couldn't find expected output file: $outputBin2\n", $exp_tag, $class_id, $PS_EXIT_SYS_ERROR) unless -f $outputBin2;
    &my_die("Couldn't find expected output file: $outputStats\n", $exp_tag, $class_id, $PS_EXIT_SYS_ERROR) unless -f $outputStats;

    # Get the statistics on the processed image
    my $statsFile;		# File handle
    open $statsFile, $outputStats or &my_die("Can't open statistics file $outputStats: $!", $exp_tag, $class_id, $PS_EXIT_SYS_ERROR);
    my @contents = <$statsFile>; # Contents of file
    close $statsFile;
    my $mdcParser = PS::IPP::Metadata::Config->new;	# Parser for metadata config files
    my $metadata = $mdcParser->parse(join "", @contents) or
	&my_die("Unable to parse metadata config doc", $exp_tag, $class_id, $PS_EXIT_PROG_ERROR);
    $stats->parse($metadata) or
	&my_die("Unable to find all values in statistics output.\n", $exp_tag, $class_id, $PS_EXIT_PROG_ERROR);
}

# Add the processed file to the database
$outputImage = $ipprc->convert_filename_relative( $outputImage);
$outputRoot  = $ipprc->convert_filename_relative( $outputRoot );

my $bg = ($stats->bg_mean() or 'NAN');
my $bg_stdev = ($stats->bg_stdev() or 'NAN');
my $bg_mean_stdev = ($stats->bg_mean_stdev() or 'NAN');

unless ($no_update) {
    # Command to run chiptool
    my $command = "$chiptool -addprocessedimfile";
    $command .= " -exp_tag $exp_tag";
    $command .= " -class_id $class_id";
    $command .= " -recip " . RECIPE;
    $command .= " -uri $outputImage";
    $command .= " -path_base $outputRoot";
    $command .= " -bg $bg -bg_stdev $bg_stdev -bg_mean_stdev $bg_mean_stdev";
    $command .= " -dbname $dbname" if defined $dbname;

    my ( $success, $error_code, $full_buf, $stdout_buf, $stderr_buf ) =
	run(command => $command, verbose => 1);
    unless ($success) {
	$error_code = (($error_code >> 8) or $PS_EXIT_PROG_ERROR);
	warn("Unable to perform chiptool -addprocessedimfile: $error_code\n");
	exit($error_code);
    }

    unlink $outputStats;
}


sub my_die
{
    my $msg = shift; # Warning message on die
    my $exp_tag = shift; # Exposure tag
    my $class_id = shift; # Class identifier
    my $exit_code = shift; # Exit code to add

    warn($msg);
    if ($exp_tag and $class_id and not $no_update) {
	my $command = "$chiptool -addprocessedimfile";
	$command .= " -exp_tag $exp_tag";
	$command .= " -class_id $class_id";
	$command .= " -code $exit_code";
	$command .= " -uri $outputImage";
	$command .= " -recip " . RECIPE;
	$command .= " -dbname $dbname" if defined $dbname;
        system ($command);
    }
    exit $exit_code;
}

END {
    my $status = $?;
    system("sync") == 0
        or die "failed to execute sync: $!" ;
    $? = $status;
}

__END__
