#!/usr/bin/env perl

use warnings;
use strict;
use Carp;

## report the program and machine
use Sys::Hostname;
my $host = hostname();
print "\n\n";
print "Starting script $0 on $host\n\n";

use vars qw( $VERSION );
$VERSION = '0.01';

use IPC::Cmd 0.36 qw( can_run run );
use PS::IPP::Metadata::Config;
use PS::IPP::Metadata::Stats;
use PS::IPP::Metadata::List qw( parse_md_list );
use PS::IPP::Config 1.01 qw( :standard );
use File::Temp qw( tempfile );

my $ipprc = PS::IPP::Config->new(); # IPP configuration

use Getopt::Long qw( GetOptions :config auto_help auto_version gnu_getopt );
use Pod::Usage qw( pod2usage );

my ( $exp_tag, $cam_id, $camera, $outroot, $recipe, $dbname, $reduction, $dvodb, $verbose, $no_update,
     $no_op, $redirect, $save_temps );
GetOptions(
    'exp_tag=s'          => \$exp_tag, # Exposure identifier
    'cam_id=s'          => \$cam_id, # Camtool identifier
    'recipe=s'          => \$recipe, # Recipe to use
    'camera|c=s'        => \$camera, # Camera
    'dbname|d=s'        => \$dbname, # Database name
    'outroot|w=s'       => \$outroot, # output file base name
    'reduction=s'       => \$reduction, # Reduction class
    'dvodb|w=s'         => \$dvodb,  # output DVO database
    'verbose'           => \$verbose,   # Print to stdout
    'no-update'         => \$no_update, # Update the database?
    'no-op'             => \$no_op, # Don't do any operations?
    'redirect-output'   => \$redirect,
    'save-temps'        => \$save_temps, # Save temporary files?
    ) or pod2usage( 2 );

pod2usage( -msg => "Unknown option: @ARGV", -exitval => 2 ) if @ARGV;
pod2usage(
          -msg => "Required options: --exp_tag --cam_id --camera --outroot",
          -exitval => 3,
          ) unless
    defined $exp_tag and
    defined $cam_id and
    defined $outroot and
    defined $camera;

$ipprc->define_camera($camera);

my $logDest = $ipprc->filename("LOG.EXP", $outroot) or &my_die("Missing entry from camera config", $cam_id, $PS_EXIT_CONFIG_ERROR);

$ipprc->redirect_output($logDest) if $redirect;

# Recipes to use based on reduction class
$reduction = 'DEFAULT' unless defined $reduction;

my $recipe1 = $ipprc->reduction($reduction, 'JPEG_BIN1'); # Recipe to use
&my_die("Unrecognised JPEG recipe", $cam_id, $PS_EXIT_CONFIG_ERROR) unless defined $recipe1;

my $recipe2 = $ipprc->reduction($reduction, 'JPEG_BIN2'); # Recipe to use
&my_die("Unrecognised JPEG recipe", $cam_id, $PS_EXIT_CONFIG_ERROR) unless defined $recipe2;

# values to extract from output metadata and the stats to calculate
# these should be coming from the psastro results
my $CHIPSTATS =
    [
        #          PPSTATS KEYWORD         STATISTIC          CHIPTOOL FLAG
        { name => "bg",             type => "mean",  flag => "-bg",             dtype => "float" },
        { name => "bg_stdev",       type => "rms",   flag => "-bg_stdev",       dtype => "float" },
        { name => "bg_mean_stdev",  type => "stdev", flag => "-bg_mean_stdev",  dtype => "float" },
        { name => "bias",           type => "mean",  flag => "-bias",           dtype => "float" },
        { name => "bias_stdev",     type => "rms",   flag => "-bias_stdev",     dtype => "float" },
        { name => "fringe_0",       type => "mean",  flag => "-fringe_0",       dtype => "float" },
        { name => "fringe_1",       type => "rms",   flag => "-fringe_1",       dtype => "float" },
        { name => "fringe_0",       type => "stdev", flag => "-fringe_2",       dtype => "float" },
#        { name => "sigma_ra",       type => "rms",   flag => "-sigma_ra",       dtype => "float" },
#        { name => "sigma_dec",      type => "rms",   flag => "-sigma_dec",      dtype => "float" },
        { name => "ap_resid",       type => "mean",  flag => "-ap_resid",       dtype => "float" },
        { name => "ap_resid_stdev", type => "rms",   flag => "-ap_resid_stdev", dtype => "float" },
        { name => "zp_mean",        type => "mean",  flag => "-zp_mean",        dtype => "float" },
        { name => "zp_stdev",       type => "rms",   flag => "-zp_stdev",       dtype => "float" },
        { name => "fwhm_major",     type => "mean",  flag => "-fwhm_major",     dtype => "float" },
        { name => "fwhm_minor",     type => "mean",  flag => "-fwhm_minor",     dtype => "float" },
        { name => "dtime_detrend",  type => "sum",   flag => "-dtime_detrend",  dtype => "float" },
        { name => "dtime_photom",   type => "sum",   flag => "-dtime_photom",   dtype => "float" },
        { name => "dtime_astrom",   type => "sum",   flag => "-dtime_astrom",   dtype => "float" },
        { name => "n_stars",        type => "sum",   flag => "-n_stars",        dtype => "int"   },
        { name => "n_extended",     type => "sum",   flag => "-n_extended",     dtype => "int"   },
        { name => "n_cr",           type => "sum",   flag => "-n_cr",           dtype => "int"   },
        ];
my $chipStats = PS::IPP::Metadata::Stats->new($CHIPSTATS); # Stats parser

# values to extract from camera-level output metadata and the stats to calculate
my $CAMSTATS =
   [
       #          PPSTATS KEYWORD         STATISTIC          CHIPTOOL FLAG
      { name => "CERROR",         type => "rms",   flag => "-sigma_ra",       dtype => "float" },
      { name => "CERROR",         type => "rms",   flag => "-sigma_dec",      dtype => "float" },
      { name => "DT_ASTR",        type => "sum",   flag => "-dtime_astrom",   dtype => "float" },
      { name => "NASTRO",         type => "sum",   flag => "-n_astrom",       dtype => "int"   },
#     { name => "ZP??",           type => "mean",  flag => "-zp_mean",        dtype => "float" },
#     { name => "ZP??",           type => "rms",   flag => "-zp_stdev",       dtype => "float" },
   ];
my $camStats = PS::IPP::Metadata::Stats->new($CAMSTATS); # Stats parser

# Look for programs we need
my $missing_tools;
my $camtool = can_run('camtool') or (warn "Can't find camtool" and $missing_tools = 1);
my $ppImage = can_run('ppImage') or (warn "Can't find ppImage" and $missing_tools = 1);
my $ppConfigDump = can_run('ppConfigDump') or (warn "Can't find ppConfigDump" and $missing_tools = 1);

# test for addstar and psastro:
my $psastro = can_run('psastro') or (warn "Can't find psastro" and $missing_tools = 1);
my $addstar = can_run('addstar') or (warn "Can't find addstar" and $missing_tools = 1);

if ($missing_tools) {
    warn("Can't find required tools.");
    exit($PS_EXIT_CONFIG_ERROR);
}

my $mdcParser = PS::IPP::Metadata::Config->new; # Parser for metadata config files

# Get list of component files
my $files;                      # Array of component files
{
    my $command = "$camtool -pendingimfile -cam_id $cam_id"; # Command to run
    $command .= " -dbname $dbname" if defined $dbname;
    my ( $success, $error_code, $full_buf, $stdout_buf, $stderr_buf ) =
        run(command => $command, verbose => $verbose);
    unless ($success) {
        $error_code = (($error_code >> 8) or $PS_EXIT_PROG_ERROR);
        &my_die("Unable to perform camtool: $error_code", $cam_id, $error_code);
    }
    my $metadata = $mdcParser->parse(join "", @$stdout_buf) or
        &my_die("Unable to parse metadata config doc", $cam_id, $PS_EXIT_PROG_ERROR);

    # extract the metadata for the files into a hash list
    $files = parse_md_list($metadata) or
        &my_die("Unable to parse metadata list", $cam_id, $PS_EXIT_PROG_ERROR);

    # extract the stats from the metadata
    unless ($chipStats->parse($metadata)) {
        &my_die("Unable to find all values in statistics output.\n", $cam_id, $PS_EXIT_PROG_ERROR);
    }
}

### not needed to have such an extensive temp file name.
my ($list1File, $list1Name) = tempfile( "$exp_tag.cm.$cam_id.b1.list.XXXX", UNLINK => !$save_temps ); # For binning 1
my ($list2File, $list2Name) = tempfile( "$exp_tag.cm.$cam_id.b2.list.XXXX", UNLINK => !$save_temps ); # For binning 2
my ($list3File, $list3Name) = tempfile( "$exp_tag.cm.$cam_id.b3.list.XXXX", UNLINK => !$save_temps ); # For astrometry

# XXX we perform astrometry iff photometry output exists
my $chipObjects;
my $chipObjectsExist = 0;
foreach my $file (@$files) {
    # use the path_base as OUTPUT root and convert the filenames with ipprc->filename:
    my $class_id = $file->{class_id};

    # If there is only one chip, we use this name for the input to addstar
    # we expect the chip analysis stage to produce psphot output (cmf file) and two binned images
    $chipObjects = $ipprc->filename("PSPHOT.OUTPUT", $file->{path_base}, $class_id);
    print $list1File ($ipprc->filename("PPIMAGE.BIN1", $file->{path_base}, $class_id) . "\n");
    print $list2File ($ipprc->filename("PPIMAGE.BIN2", $file->{path_base}, $class_id) . "\n");
    print $list3File ($ipprc->convert_filename_absolute($chipObjects) . "\n");

    # if any of the output chip photometry files exist, we can run psastro / addstar below
    if ($ipprc->file_exists($chipObjects)) {
        $chipObjectsExist = 1;
    }
}
close $list1File;
close $list2File;
close $list3File;

# Output products
$ipprc->outroot_prepare($outroot);

# the camera configurations should define the psastro output to be a single file (MEF), regardless of the inputs
my $jpeg1      = $ipprc->filename("PPIMAGE.JPEG1",      $outroot) or &my_die("Missing entry from camera config", $cam_id, $PS_EXIT_CONFIG_ERROR);
my $jpeg2      = $ipprc->filename("PPIMAGE.JPEG2",      $outroot) or &my_die("Missing entry from camera config", $cam_id, $PS_EXIT_CONFIG_ERROR);
my $fpaObjects = $ipprc->filename("PSASTRO.OUTPUT",     $outroot) or &my_die("Missing entry from camera config", $cam_id, $PS_EXIT_CONFIG_ERROR);
my $fpaStats   = $ipprc->filename("PSASTRO.STATS",      $outroot) or &my_die("Missing entry from camera config", $cam_id, $PS_EXIT_CONFIG_ERROR);
my $traceDest  = $ipprc->filename("TRACE.EXP",          $outroot) or &my_die("Missing entry from camera config", $cam_id, $PS_EXIT_CONFIG_ERROR);

# convert supplied DVO database name to UNIX filename
my $dvodbReal;
if (defined $dvodb) {
    $dvodbReal = $ipprc->dvo_catdir( $dvodb ); # catdir for DVO
    $dvodbReal = $ipprc->convert_filename_absolute( $dvodbReal );
}

unless ($no_op) {

    ## build the output JPEG images first so we get them even if the astrometry fails

    # Make the jpeg for binning 1
    {
        my $command = "$ppImage -list $list1Name $outroot -recipe PPIMAGE $recipe1"; # Command to run
        $command .= " -dbname $dbname" if defined $dbname;

        my ( $success, $error_code, $full_buf, $stdout_buf, $stderr_buf ) =
            run(command => $command, verbose => $verbose);
        unless ($success) {
            $error_code = (($error_code >> 8) or $PS_EXIT_PROG_ERROR);
            &my_die("Unable to perform ppImage: $error_code", $cam_id, $error_code);
        }
        &my_die("Unable to find expected output file: $jpeg1", $cam_id, $PS_EXIT_PROG_ERROR) unless -f $ipprc->file_resolve($jpeg1);
    }

    # Make the jpeg for binning 2
    {
        my $command = "$ppImage -list $list2Name $outroot -recipe PPIMAGE $recipe2"; # Command to run
        $command .= " -dbname $dbname" if defined $dbname;

        my ( $success, $error_code, $full_buf, $stdout_buf, $stderr_buf ) =
            run(command => $command, verbose => $verbose);
        unless ($success) {
            $error_code = (($error_code >> 8) or $PS_EXIT_PROG_ERROR);
            &my_die("Unable to perform ppImage: $error_code", $cam_id, $error_code);
        }
        &my_die("Unable to find expected output file: $jpeg2", $cam_id, $PS_EXIT_PROG_ERROR) unless -f $ipprc->file_resolve($jpeg2);
    }

    # only run psastro / addstar if any of the output chip astrometry files exist (should we test for successful astrometry?)
    if ($chipObjectsExist) {
        # run psastro on the chipObjects, producing fpaObjects
        # XXX add a ppStats call which will collect the astrometry stats
        my $command;
        $command  = "$psastro -list $list3Name $outroot";
        $command .= " -tracedest $traceDest -log $logDest";
	$command .= " -stats $fpaStats -recipe PPSTATS CHIPSTATS";
        $command .= " -dbname $dbname" if defined $dbname;

        my ( $success, $error_code, $full_buf, $stdout_buf, $stderr_buf ) =
            run(command => $command, verbose => $verbose);
        unless ($success) {
            $error_code = (($error_code >> 8) or $PS_EXIT_PROG_ERROR);
            &my_die("Unable to perform psastro: $error_code", $cam_id, $error_code);
        }
        # XXX do we want to give an error if astrometry fails here?
        &my_die("Unable to find expected output file: $fpaObjects", $cam_id, $PS_EXIT_PROG_ERROR) unless -f $ipprc->file_resolve($fpaObjects);
        &my_die("Unable to find expected output file: $fpaStats",   $cam_id, $PS_EXIT_PROG_ERROR) unless -f $ipprc->file_resolve($fpaObjects);

	# Get the statistics on the processed image
	my $statsFile;              # File handle
	open $statsFile, $ipprc->file_resolve($fpaStats) or &my_die("Can't open statistics file $fpaStats: $!", $cam_id, $PS_EXIT_SYS_ERROR);
	my @contents = <$statsFile>; # Contents of file
	close $statsFile;

	# parse the statistics MDC file
	my $mdcParser = PS::IPP::Metadata::Config->new();   # Parser for metadata config files
	my $metadata = $mdcParser->parse(join "", @contents);
	unless ($metadata) {
	    &my_die("Unable to parse metadata config doc", $cam_id, $PS_EXIT_PROG_ERROR);
	}

	# extract the stats from the metadata
	unless ($camStats->parse($metadata)) {
	    &my_die("Failure extracting metadata from the statistics output file.\n", $cam_id, $PS_EXIT_PROG_ERROR);
	}

        # run addstar on the output fpaObjects (if a DVO database is defined)
        if (defined $dvodbReal) {
            # XXX this construct requires the user to have a valid .ptolemyrc
            # XXX which in turn points at ippconfig/dvo.site
            # require a defined output dvo database to run addstar (ie, refuse to use the .ptolemyrc default)
            # XXX this needs to be converted to addstar_client...

            my $camdir = $ipprc->dvo_cameradir(); # Camera directory for addstar
            my $command;
            $command  = "$addstar -D CAMERA $camdir -update";
            $command .= " -D CATDIR $dvodbReal";

            my $realFile = $ipprc->file_resolve($fpaObjects);
            $command .= " $realFile";

            my ( $success, $error_code, $full_buf, $stdout_buf, $stderr_buf ) =
                run(command => $command, verbose => $verbose);
            unless ($success) {
                $error_code = (($error_code >> 8) or $PS_EXIT_PROG_ERROR);
                &my_die("Unable to perform addstar: $error_code", $cam_id, $error_code);
            }
        }
    }
}

my $fpaCommand = "$camtool -addprocessedexp";
$fpaCommand .= " -cam_id $cam_id";
$fpaCommand .= " -uri UNKNOWN";
$fpaCommand .= " -path_base $outroot";
$fpaCommand .= " -hostname $host" if defined $host;
$fpaCommand .= " -dbname $dbname" if defined $dbname;
$fpaCommand .= $chipStats->cmdflags();
$fpaCommand .= $camStats->cmdflags();

# Add the result into the database
unless ($no_update) {
    my ( $success, $error_code, $full_buf, $stdout_buf, $stderr_buf ) =
        run(command => $fpaCommand, verbose => $verbose);
    unless ($success) {
        $error_code = (($error_code >> 8) or $PS_EXIT_PROG_ERROR);
        warn("Unable to add result to database: $error_code\n");
        exit($error_code);
    }
} else {
    print "skipping command: $fpaCommand\n";
}


sub my_die
{
    my $msg = shift; # Warning message on die
    my $cam_id = shift; # Camtool identifier
    my $exit_code = shift; # Exit code to add

    carp($msg);
    if (defined $cam_id and not $no_update) {
        my $command = "$camtool -addprocessedexp";
	$command .= " -cam_id $cam_id";
	$command .= " -uri UNKNOWN";
	$command .= " -code $exit_code";
	$command .= " -path_base $outroot";
        $command .= " -hostname $host" if defined $host;
        $command .= " -dbname $dbname" if defined $dbname;
        $command .= " -path_base $outroot" if defined $outroot;
        system ($command);
    }
    exit $exit_code;
}


END {
    my $status = $?;
    system("sync") == 0
        or die "failed to execute sync: $!" ;
    $? = $status;
}

__END__
