#!/usr/bin/env perl

# Copyright (C) 2006-2008  Joshua Hoblitt
#
# $Id: dsfilesetls,v 1.10 2008-05-20 01:09:29 jhoblitt Exp $

use strict;
use warnings FATAL => qw( all );

use vars qw( $VERSION );
$VERSION = '0.02';

use DataStore;

use Getopt::Long qw( GetOptions :config auto_help auto_version gnu_getopt );
use Pod::Usage qw( pod2usage );

my ($uri, $timeout, $no_proxy);

GetOptions(
    'uri|u=s'           => \$uri,
    'timeout|t=s'       => \$timeout,
    'no-proxy'          => \$no_proxy,
) or pod2usage( 2 );

pod2usage( -msg => "Unknown option: @ARGV", -exitval => 2 ) if @ARGV;
pod2usage(
    -msg => "Required options: --uri",
    -exitval => 3,
) unless defined $uri;

# default http request timeout is 30s
$timeout ||= 30;
$no_proxy = 0 if !defined $no_proxy;

if (!($uri =~ /\/index\.txt$/)) {
    $uri .= '/index.txt'
} 

my $response = DataStore::FileSet->new( uri => $uri )->request(
        ua_args  => { timeout => $timeout },
        no_proxy => $no_proxy,
    );

unless (defined $response and $response->is_success) {
    warn "request failed: ", $response->status_line;
    exit($response->code - 300);
}

# file retreival succeed

my $data = $response->data;

unless ($data) {
    warn "no files found";
    exit(0);
}

print "# uri fileid bytes md5sum type \n";
foreach my $fs (@$data) {
    print 
        $fs->uri, " ",
        $fs->fileid, " ",
        $fs->bytes, " ",
        $fs->md5sum || 0, " ",
        $fs->type;
    print " ", join(" ", @{$fs->extra}) if defined $fs->extra;   
    print "\n";
}

__END__

=pod

=head1 NAME

dsfilesetls - list all the Files under a FileSet from a DataStore server

=head1 SYNOPSIS

    dsfilesetls --uri <uri> 

=head1 DESCRIPTION

=head1 OPTIONS

=over 4

=item * --uri|-u <uri>

The URI of the file to be retrieved.

=item * --timeout|-t

The ammount of time (in seconds) to wait for a response from the DataStore
after making an HTTP request.  The default is 30s.

Optional.

=item * --no-proxy

Do not load proxy environment variables.

Optional.

=back

=head1 CREDITS

Just me, myself, and I.

=head1 SUPPORT

Please contact the author directly via e-mail.

=head1 AUTHOR

Joshua Hoblitt <jhoblitt@cpan.org>

=head1 COPYRIGHT

Copyright (C) 2006-2008  Joshua Hoblitt.  All rights reserved.

This program is free software; you can redistribute it and/or modify it under
the terms of the GNU General Public License as published by the Free Software
Foundation; either version 2 of the License, or (at your option) any later
version.

This program is distributed in the hope that it will be useful, but WITHOUT ANY
WARRANTY; without even the implied warranty of MERCHANTABILITY or FITNESS FOR A
PARTICULAR PURPOSE.  See the GNU General Public License for more details.

You should have received a copy of the GNU General Public License along with
this program; if not, write to the Free Software Foundation, Inc., 59 Temple
Place - Suite 330, Boston, MA  02111-1307, USA.

The full text of the license can be found in the L<perlgpl> Pod as supplied
with Perl 5.8.1 and later.

=head1 SEE ALSO

L<dsget>, L<dsleech>, L<dsrootls>, L<dsproductls>, L<dsfilesetls>, L<DataStore>

=cut
