#!/usr/bin/env perl

#
# Copy warp outputs to the current directory
#

use warnings;
use strict;

use DBI;
use constant DB_SOCKET => '/var/run/mysqld/mysqld.sock'; # Socket for mysql
use Getopt::Long qw( GetOptions :config auto_help auto_version gnu_getopt );

use constant EXTENSIONS => { 'IMAGE' => '.fits', # Image
                             'MASK' => '.mask.fits', # Mask
                             'VARIANCE' => '.wt.fits', # Variance
                             'SOURCES' => '.cmf', # Sources
                             'PSF' => '.psf', # Point-Spread Function
                         };

my ($db_host, $db_name, $db_user, $db_pw); # Database details
my ($warp_id);                  # Warp of interest
my ($skycell_id);               # Skycell of interest
my ($input);                    # Input list
my ($products);                 # Products of interest
my ($muggle);                   # No magicked inputs?

GetOptions(
           'dbhost=s' => \$db_host, # Database host name
           'dbname=s' => \$db_name, # Database name
           'dbuser=s' => \$db_user, # Database user
           'dbpass=s' => \$db_pw, # Database p/w
           'warp_id=s' => \$warp_id, # Warp identifier
           'skycell_id=s' => \$skycell_id, # Skycell identifier
           'products=s' => \$products, # Products of interest
           'muggle'   => \$muggle, # No magicked inputs?
           ) or 
die "Unable to parse arguments.\n";
die "Unknown option: @ARGV\n" if @ARGV;
die "Required options: --dbhost --dbname --dbuser --dbpass --warp_id\n"
    unless defined $db_host
    and defined $db_name
    and defined $db_user
    and defined $db_pw
    and defined $warp_id;

# Database connection
my $db = DBI->connect( "DBI:mysql:database=$db_name;host=$db_host;mysql_socket=" . DB_SOCKET(),
                       $db_user,
                       $db_pw,
                       { RaiseError => 1, AutoCommit => 1 }
                       ) or die "Unable to connect to database: $DBI::errstr";

# Query to run
my $sql = "SELECT path_base FROM warpSkyfile WHERE warp_id = $warp_id AND fault = 0 AND quality = 0";
$sql .= " AND skycell_id = \'$skycell_id\'" if defined $skycell_id;

# List of diffs
my $warps = $db->selectcol_arrayref( $sql,
                                     { Columns => [1] }
                                     ) or die "Unable to execute SQL: $DBI::errstr";

my @products;                   # Array of products
if (defined $products) {
    @products = split /,/, $products;
} else {
    @products = keys %{EXTENSIONS()};
}

foreach my $warp ( @$warps ) {
    foreach my $product ( @products ) {
        copy_extension( $warp, ${EXTENSIONS()}{$product} );
    }
}

# Pau.


sub copy_extension
{
    my $path = shift;           # Path to copy
    my $ext = shift;            # Extension to copy

    my $file = "$path$ext"; # File

    if (defined $muggle and $ext ne ".psf") {
        my @file = split /\//, $file;
        my $last = pop @file;
        push @file, "SR_$last";
        $file = join '/', @file;
    }

    my $source = `ipp_datapath.pl $file` or die "Unable to locate $file\n"; # Actual file
    chomp $source;
    my ($target) = $source =~ m|^.*[:/](.*)|; # Target name
    !system "cp $source $target" or die "Unable to copy $source\n";
}
