Index: /trunk/ippTools/configure.ac
===================================================================
--- /trunk/ippTools/configure.ac	(revision 8691)
+++ /trunk/ippTools/configure.ac	(revision 8692)
@@ -18,4 +18,20 @@
 PKG_CHECK_MODULES([IPPDB], [ippdb >= 0.0.34]) 
 
+AC_PROG_PERL_MODULES(
+  [IPC::Cmd], ,
+  [AC_MSG_ERROR(perl module IPC::Cmd is required)]
+)
+
+AC_PROG_PERL_MODULES(
+  [PS::IPP::Metadata], ,
+  [AC_MSG_ERROR(perl module PS::IPP::Metadata is required)]
+)
+
+AC_PROG_PERL_MODULES(
+  [PS::IPP::Metadata::Config], ,
+  [AC_MSG_ERROR(perl module PS::IPP::Metadata::Config is required)]
+)
+
+
 dnl pxtools_CFLAGS="-Wall -Werror -std=c99"
 pxtools_CFLAGS="-Wall -std=c99"
@@ -25,4 +41,5 @@
   Makefile
   src/Makefile
+  scripts/Makefile
 ])
 AC_OUTPUT
Index: /trunk/ippTools/m4/ac_prog_perl_modules.m4
===================================================================
--- /trunk/ippTools/m4/ac_prog_perl_modules.m4	(revision 8692)
+++ /trunk/ippTools/m4/ac_prog_perl_modules.m4	(revision 8692)
@@ -0,0 +1,53 @@
+dnl @synopsis AC_PROG_PERL_MODULES([MODULES], [ACTION-IF-TRUE], [ACTION-IF-FALSE])
+dnl
+dnl Checks to see if the the given perl modules are available. If true
+dnl the shell commands in ACTION-IF-TRUE are executed. If not the shell
+dnl commands in ACTION-IF-FALSE are run. Note if $PERL is not set (for
+dnl example by calling AC_CHECK_PROG, or AC_PATH_PROG),
+dnl AC_CHECK_PROG(PERL, perl, perl) will be run.
+dnl
+dnl Example:
+dnl
+dnl   AC_CHECK_PERL_MODULES(Text::Wrap Net::LDAP, ,
+dnl                         AC_MSG_WARN(Need some Perl modules)
+dnl
+dnl @category InstalledPackages
+dnl @author Dean Povey <povey@wedgetail.com>
+dnl @version 2002-09-25
+dnl @license AllPermissive
+
+AC_DEFUN([AC_PROG_PERL_MODULES],[
+    ac_perl_modules="$1"
+    # Make sure we have perl
+    if test -z "$PERL"; then
+        AC_CHECK_PROG(PERL,perl,perl)
+    fi
+
+    if test "x$PERL" != x; then
+        ac_perl_modules_failed=0
+        for ac_perl_module in $ac_perl_modules; do
+            AC_MSG_CHECKING(for perl module $ac_perl_module)
+
+            # Would be nice to log result here, but can't rely on autoconf
+            # internals
+            $PERL "-M$ac_perl_module" -e exit > /dev/null 2>&1
+            if test $? -ne 0; then
+                AC_MSG_RESULT(no);
+                ac_perl_modules_failed=1
+            else
+                AC_MSG_RESULT(ok);
+            fi
+        done
+
+        # Run optional shell commands
+        if test "$ac_perl_modules_failed" = 0; then
+            :
+            $2
+        else
+            :
+            $3
+        fi
+    else
+        AC_MSG_WARN(could not find perl)
+    fi
+])